Benny Pedersen's Homepage about photo.

Benny Pedersen's Homepage about photo.

My new site is here

Adobe PhotoShop, Tips Tricks, Photos, Scripts, Tools...
Recovery, BartPE Stuff

To see my pictures from the burning factory of fireworks explode, click the above link named Photos.

Nearby my home in Kolding (Denmark)

June 17, 2004 - 04:20 AM June 23, 2004 - 05:09 AM

More photos here: Gallery

WhiteBalance on the kitchentable.

If you put a white paper on the kitchentable, then it can be used to
adjust the WB. The result can easily be a realistic picture
that looks as taken outdoor - but isn't at all.

Example:

An animal of stone (called fossil).
We saw the stone from the top of the cliff. 5 minutes later I hang menacing in a robe more than 10 metres over the sea.
It was both difficulty and very dangerous. Hurricane, volcano and snow... but I was lucky to get a good macro shot, which I like. (Shutter: 1/4 sec., F: 8)
The picture is adjusted a little in "Photoshop Elements 2" with the filter Unsharp Mask, and Quick Fix: Levels, Contrast and Colors.

	1. As you can see on this picture, after seen the "AND THE WINNER IS" - photo, dragonfly in a flower - (magazine "Digital Foto" numb 10, page 13), I was motivated to take some macros.
	2b. By running fast after shooting this picture, I get to the other side, before the animal was able to fly away.

1: 3:	2a: 2c:	2b: 2d:

3. When the shooting was done, the little creature was so much exhausted, that it threw its legs on my kitchen table, and toke a nap on its back.

Adobe PhotoShop. Tips.
While the layers menu are on, try: Hold the Ctrl key and left click a layer. Press F3 (copy), press F4 (insert).

Scripts.

Purpose: Make unique filenames. (Also see "jpg2numbers.vbs" on page 2)
"jpg2dateTime.wsf" is working in WinXP.

To copy in the following textbox: Hold Ctrl, Press A, Press C or X

<PACKAGE><JOB ID="jpg2dateTime.wsf">
<!--
  *** Renames any JPG file to the date that the picture was taken ***

'1. Input:      What folder?
  '2. Make array: JPG files in that folder (subFolders TRUE or FALSE)
  '3. Sort array.
  '4. Loop array: Get EXIF YYMMDDhhmm (Year month day hour minute)
  '5. Rename JPG files:   "YYMMDD_hhmmss.jpg"
  '6. If cannot, tries:   "YYMMDD_hhmmss_1.jpg"  (and so, ... 299)
  '7. Create a batch file in TEMP named "undo.bat".

'If time seconds cannot be decided, 29 is used, "YYMMDD_hhmm29.jpg"
  'If the 11 first is YYMMDD_hhmm and true, the JPG won't be renamed.
  'If you drag & drop a file or folder, the jpg2dateTime script will
  '   use the path as default value for the input.
  'If you are prompted about overwriting a file "undo.bat", then just
  '   choose ignore, and the jpg2dateTime script will continue, :-).
  'BTW. An easy way to open the TEMP folder is: START, RUN, %TMP%

'You can modify:
  '1. Substitute TRUE in line numb 33, subFolders=TRUE with FALSE
  '2. Substitute "MyDocuments" in line numb 42 with "Desktop", or
  '   path = wso.specialFolders("MyDocuments") & "\DCIM\"   with:
  '   path = "C:\JPGs\" 'Ending backslash maybe useful, not required,
  '   whatever, the path is only used as default value for the input.

-->
<SCRIPT language="JScript">
  function jsSort(arr){return arr.toArray().sort().join('*')}
</SCRIPT>
<SCRIPT language="VBScript"> ' including subFolders, TRUE or FALSE:
  dim renamed, countExif, countNoExif, subFolders: subFolders=TRUE
  dim jpgFiles, wFile
  dim fso: set fso = createObject("scripting.fileSystemObject")
  dim wso: set wso = createObject("wScript.shell")
  dim msg: msg = "This script tries to rename any JPG file as the" &_
                 " date that the picture was taken." & string(2,vbLf)
  if(subFolders)then
    msg = msg & "Search including subfolder(s)." & string(2,vbLf)
  end if
  dim path: path = wso.specialFolders("MyDocuments") & "\DCIM\"
  path = getPath("Input", msg & vbLf & "Path:", path, false)
  dim undoFile: undoFile = fso.getSpecialFolder(2) & "\undo.bat"
  msg = 0
  do while(fso.fileExists(undoFile))
    select case msgBox("The following file will be overwritten:" &_
                       vbLf & undoFile, 2+64+512, "jpg2dateTime")
      case vbAbort : wScript.quit
      case vbIgnore: exit do
    end select
    msg=msg+1: if(msg=2)then msgBox "Go" & msg & "quit": wScript.quit
  loop
  jpgFiles = split(getFileList(path, subFolders, empty), "*")
  jpgFiles = split(jsSort(jpgFiles), "*")
  set wFile = fso.openTextFile(undoFile, 2, true)
  wFile.writeLine "@echo off"
  main
  wFile.close: set wFile=nothing
  msg= "jpg2dateTime" & vbLf & path & string(2,vbLf) & "Subfolder(s)"
  if not(subFolders) then msg = msg & " not"
  msg = msg & " included." & string(2,vbLf) &_
        "Counted JPGs, EXIF:   " & vbTab & countExif & " file(s)" &_
        vbLf & "Counted JPGs, no EXIF:" & vbTab & countNoExif &_
        " file(s)" & string(2,vbLf) &_
        "Renamed:" & string(2,vbTab) & renamed & " JPG file(s)."
  if(renamed)then
       msg = msg & string(2,vbLf) & "Created:" & vbLf & undoFile
  else fso.deleteFile(undoFile)
  end if
  msgBox msg, 64, "All done"

sub main:  countExif=0: countNoExif=0: renamed=0
  dim i,file,newBaseName13,ren,folder,fileName,baseName,newBaseName
  dim newFileName,newFullName: const ext = ".jpg"
  on error resume next
  for i = 1 to uBound(jpgFiles)
    file = jpgFiles(i)
    newBaseName13 = YYMMDD_hhmmss(file)
    if(len(newBaseName13)<13)then
      countNoExif = countNoExif +1
    else
      countExif = countExif +1
      fileName = fso.getFileName(file)
      if(true)then' [available to put an extra condition for rename].
        ren = true: j = empty
        folder   = fso.getParentFolderName(file) & "\"
        baseName = fso.getBaseName(fileName)
        do: newBaseName = newBaseName13 & replace(j," ","_")
            newFileName = newBaseName & ext
            newFullName = folder & newFileName
            err.clear
            if(left(baseName,11) = left(newBaseName,11))then
              ren = false: exit do
            end if
            fso.moveFile file, newFullName
            j= chr(32) & j +1
        loop while(err)and(j<300)
        if(err)then
          msgBox "Something is wrong ?", 48: exit sub
        elseIf(ren)then
          renamed = renamed +1
          wFile.writeLine "ren """ & newFullName &_
                          """ """ & fileName & """"
        end if
      end if
    end if
  next
end sub

function YYMMDD_hhmmss(fileSpec)
  dim fsoDLM,oFolder,exif25,YYdate,MMdate,DDdate,hhTime,mmTime,ssTime
  fsoDLM = fso.getFile(fileSpec).dateLastModified
  set oFolder = createObject("shell.application")._
           nameSpace(fso.getParentFolderName(fileSpec))
  exif25 = oFolder.getDetailsOf(oFolder.parseName(fso._
           getFileName(fileSpec)), 25)
  YYdate = mid(exif25,9,2): hhTime = mid(exif25,12,2)
  MMdate = mid(exif25,4,2): mmTime = mid(exif25,15,2)
  DDdate = mid(exif25,1,2): ssTime = "29"
  if(exif25 = left(fsoDLM, len(exif25)))then ssTime = right(fsoDLM,2)
  YYMMDD_hhmmss = YYdate & MMdate & DDdate & "_"_
                & hhTime & mmTime & ssTime
end function

function getFileList(folderSpec, recurse, list)
  dim f
  for each f in fso.getFolder(folderSpec).files
    if(lCase(fso.getExtensionName(f)) = "jpg") then list = list & "*" & f
  next
  if(recurse)then
    for each f in fso.getFolder(folderSpec).subfolders
      getFileList f, recurse, list
    next
  end if
  getFileList = list
end function

function getPath(title, msg, default, bool) 'using fso
  dim p: on error resume next
  if(wScript.arguments.count)then
    p = wScript.arguments(abs(bool)): default = fso.getFolder(p)
    if(err)then default = fso.getParentFolderName(p)
  end if: default = replace(default & "\","\\","\")
  p = trim(inputBox(msg,title,default)): if(p="")then wScript.quit
  p = replace(p,"""",""): err.clear: p = fso.getFolder(p)
  if(err)then msgBox"Path not found:" & vbLf & p,, "Quit": wScript.quit
  getPath = p
end function

set fso = nothing: set wso = nothing
</SCRIPT></JOB></PACKAGE>

<!-- [This line along with all the following lines can be deleted]
  Benny Pedersen, http://home1.stofanet.dk/photo
  PS.: I saw that heading 27, 28 and 31, does not have a property.
  Anyhow, property number 27 contents the picture width in pixels.

Enclosure: (Maybe usefull if you want to modify the above script).
===================================================================
' EXIF.vbs - Not optimized for application(s),
' used to get conclusion(s) for construction of "jpg2dateTime.wsf".
  dim sFolder: sFolder=inputBox("Path:", "Input", "C:\myPictures\")
  if(sFolder=empty)then wScript.quit
  dim oShell, oFolder, i, arrHead(35), sFName, sInfo
  set oShell= createObject("shell.application")
  set oFolder = oShell.namespace(sFolder)
  for i=0 to 34: arrHead(i) = oFolder.getDetailsOf(oFolder.items,i)
  next
  arrHead(27)="width": arrHead(28)="height": arrHead(31)="Modified"
  for each sFName in oFolder.items
    sInfo = empty
    for i = 0 to 34
       sInfo = sInfo & "'" & right(0 & i, 2) & "  " & arrHead(i) &_
              ":" & vbTab & oFolder.getDetailsOf(sFName,i) & vbCrLf
    next
    if(vbEmpty=inputBox(string(4,vbLf)& sInfo,,sInfo))then exit for
  next
  set oShell=nothing: set oFolder=nothing

' =================================================================
'    English          Danish                    Example
'    (Source MS Web)  (WinXP SP2)               (WinXP SP2, Danish)
' -----------------------------------------------------------------
'  0 Name             Navn:                     040623_050912_.jpg
'  1 Size             Størrelse:                2.967 KB
'  2 Type             Type:                     JPEG-billede
'  3 Date Modified    Ændret den:               07-09-2004 03:49
'  4 Date Created     Dato for oprettelse:      23-09-2004 00:51
'  5 Date Accessed    Dato for adgang:          23-09-2004 00:00
'  6 Attributes       Attributter:              R
'  7 Status           Status:                   Online
'  8 Owner            Ejer:                     Alle
'  9 Author           Forfatter:
' 10 Title            Titel:
' 11 Subject          Emne:
' 12 Category         Kategori:
' 13 Pages            Sider:                    1
' 14 Comments         Kommentarer:
' 15 Copyright        Copyright:
' 16 Artist           Kunstner:
' 17 Album Title      Albumtitel:
' 18 Year             År:
' 19 Track Number     Nummer:
' 20 Genre            Genre:
' 21 Duration         Varighed:
' 22 Bit Rate         Bithastighed:
' 23 Protected        Beskyttet:
' 24 Camera Model     Kameramodel:              DiMAGE Z2
' 25 DatePictureTaken Billede taget d.:         23-06-2004 05:09
' 26 Dimensions       Dimensioner:              2216 x 1662
' 27 Not used         :                         2216 pixel
' 28 Not used         :                         1662 pixel
' 29 Not used         Episodenavn:
' 30 Company          Programbeskrivelse:
' 31 Description      :                         2004:09:07 03:49:06
' 32 File Version     Størrelse på lydsampling:
' 33 Product Name     Lydsamplingshastighed:
' 34 Product Version  Kanaler:
' =================================================================

' DatesTimes.vbs '(date and time data, extracted from every source)
' Used to get conclusion(s) for construction of "jpg2dateTime.wsf".
  dim sFolder: sFolder=inputBox("Path:", "Input", "C:\myPictures\")
  if(sFolder=empty)then wScript.quit
  dim oShell,oFolder,fso,i,f,sInfo
  set oShell= createObject("shell.application")
  set oFolder = oShell.namespace(sFolder)
  set fso = createObject("scripting.fileSystemObject")
  for each i in oFolder.items
    set f = fso.getFile(sFolder & "\" & i)
    sInfo = "'00 " & vbtab & "Name:    " & vbtab &_
                     oFolder.GetDetailsOf(i,00) & vbCrLf & vbCrLf &_
            "'03 " & vbtab & "Modified:" & vbtab &_
                     oFolder.GetDetailsOf(i,03) & vbCrLf &_
            "'31 " & vbtab & "Modified:" & vbtab &_
                     oFolder.GetDetailsOf(i,31) & vbCrLf &_
            "'fso" & vbtab & "Modified:" & vbtab &_
                     f.dateLastModified & vbCrLf &_
            "'04 " & vbtab & "Created: " & vbtab &_
                     oFolder.GetDetailsOf(i,04) & vbCrLf &_
            "'fso" & vbtab & "Created: " & vbtab &_
                     f.dateCreated & vbCrLf &_
            "'05 " & vbtab & "Accessed:" & vbtab &_
                     oFolder.GetDetailsOf(i,05) & vbCrLf &_
            "'fso" & vbtab & "Accessed:" & vbtab &_
                     f.dateLastAccessed & vbCrLf &_
            "'25 " & vbtab & "Taken:   " & vbtab &_
                     oFolder.GetDetailsOf(i,25)
    if(vbEmpty=inputBox(string(5,vbLf)& sInfo,, sInfo))then exit for
  next
  set oShell=nothing: set oFolder=nothing: set fso=nothing
' -->

A little batch file.
Purpose: Renames any JPG file in the current folder with a lowercase extension, JPG to jpg
Notice that the extension of a batch file is BAT
"JPG2jpg.bat" is only one line:

When done, update the folder view by using the F5 key.

HTML Without Clutter. "MakeThumbsIndex.WSF". Last updated Nov 20, 2004
Warning: The created HTML code contains some of my new ideas, which is newer seen.
Since it's 100% my work, you can expect to see a lot of new code stuff in here, (as usual :-)

<JOB ID="MakeThumbsIndex.wsf">
<!--
  *** Put your thumbnails on only one HTML page ***

Input, where is the thumbnails.
  Input, where is the big jpeg's.

Do not let the Jpeg folder be a subfolder in the thumbnail folder.
  Do not let the thumbnail folder be a subfolder in the Jpeg folder.

1. Make array of thumbs and jpeg's
  2. If a thumbnail can't find its jpeg, ask about delete the thumb.
  3. Write HTML files in TEMP, "index1.html" and "indexThumbs1.html"

-->
<SCRIPT language="VBScript">
  dim htmFileA, path0, thumbArr, thumbNumbOf, lngth0, msg
  dim htmFileB, path1, jpegsArr, jpegsNumbOf, lngth1
  dim deletedThumbs: deletedThumbs = 0
  dim fso: set fso = createObject("scripting.fileSystemObject")
  dim wso: set wso = createObject("wScript.shell")

' get filenames in TEMP for writing HTML
  htmFileA = fso.getSpecialFolder(2) & "\index1.html"
  htmFileB = fso.getSpecialFolder(2) & "\indexThumbs1.html"

' get default values paths (used if no drag & drop, a file/two folders)
  path0 = "C:\jpeg\thumbnails\"
  path1 = "C:\jpeg\bigger\"

' get the paths
  msg = "Where is the thumbs?" & string(2,vbLf) & "Path:"
  path0 = getPath("Input", msg, path0, false)

msg = "Where is the bigger?" & string(2,vbLf) & "Path:"
  path1 = getPath("Input", msg, path1, true)

' make arrays and other variables
  thumbArr = split(getFileList(path0, true, empty), "*")
  jpegsArr = split(getFileList(path1, true, empty), "*")
  thumbNumbOf = uBound(thumbArr)
  jpegsNumbOf = uBound(jpegsArr)
  lngth0 = len(path0) +2
  lngth1 = len(path1) +2
  msg = htmFileA

' go ahead
  set htmFileA = fso.openTextFile(htmFileA, 2, true)
  set htmFileB = fso.openTextFile(htmFileB, 2, true)
  writeHtml: set fso = nothing
  htmFileA.close: set htmFileA=nothing
  htmFileB.close: set htmFileB=nothing
  wso.run"%tmp%": wScript.sleep(99): set wso = nothing

' done
  msg = path0 & vbLf & (thumbNumbOf - deletedThumbs) & " = (" _
     & thumbNumbOf & " - " & deletedThumbs & ") thumbs." & vbLf _
     & vbLf & path1 & vbLf & jpegsNumbOf & " jpegs." _
     & string(2,vbLf) & "You may run:" & vbLf & """" & msg & """"
  msgBox msg, 64, " *** MakeThumbsIndex ***"

function getFileList(folderSpec, recurse, list): dim f
  for each f in fso.getFolder(folderSpec).files
    if(uCase(fso.getExtensionName(f))= "JPG")then list = list & "*" & f
  next
  if(recurse)then
    for each f in fso.getFolder(folderSpec).subfolders
      getFileList f, recurse, list
    next
  end if
  getFileList = list
end function

function getPath(title, byVal msg, byVal default, byVal bool)
  dim p: bool = abs(bool): on error resume next
  if(wScript.arguments.count > bool)then
    p= wScript.arguments(bool): default = fso.getFolder(p)
    if(err)then default = fso.getParentFolderName(p)
  end if: default = replace(default & "\","\\","\")
  p = replace(trim(inputBox(msg,title,default)),"""","")
  if(p="")then wScript.quit(0)
  err.clear: p= fso.getFolder(p)
  if(err)then
    msg = "Path not found:" & vbLf & p & vbLf & vbLf
    msgBox msg & vbLf & "Quit:",48,"Error": wScript.quit(1)
  end if: getPath = p
end function

sub writeHtml()
  dim tab1, tab2, tab3
  tab1 = vbTab: tab2 = string(2,tab1): tab3 = tab1 & tab2
' Code Fragmentation. Tips:
' Homer Simpsons, if you can't read the following, just read
'           the rest in the two written HTLM files, instead. :-)
  const CF1 = "parent.frames[1].document.write("
  const CF2 = "parent.frames[1].document.getElementById(""img"
  const CF3 = " visibility:hidden; filter:progid:DXImageTransform.Micros"
  const CF4 = """).style.visibility = """
  const CF5 = """ src=""' + p + imgName + '"" width=""' + w"
  const CF6 = " + '"" onClick=""flip(\'"
  dim n: n = vbCrLf
  htmFileA.write "<html>" & n & "<head><title>MyJPGs</title></head>" _
      & n & "<frameset cols=""*,30%"">" & n &_
      tab1 & "<frame frameborder=""1" _
           & """ name=""index"" src=""indexThumbs1.html"">" & n &_
      tab1 & "<frame frameborder=""0"" name=""slide"" src="""">" & n &_
      "</frameset>" & n & "</html>" & n

htmFileB.write "<html>" & n & "<head>" & n &_
  Tab1 & "<base" & string(28,chr(32)) _
       & "href = """ & replace(path0, "\", "/") & "/""" & n &_
  Tab1 & ">" & chr(60) & "script language=""javaScript""> var p = """ _
       & replace(path1, "\", "/") & "/""" & n &_
  Tab2 & "function s(p,imgName) {" & n &_
  Tab3 & "status = p + imgName;" & n &_
  Tab3 & "var w1 = ""100%"";" & n &_
  Tab3 & "var c60 = ""<"";" & n &_
  Tab3 & "parent.frames[1].document.close();" & n &_
  Tab3 & CF1 & "'<html><head><title>MyJPGs</title><style>')" & n &_
  Tab3 & CF1 & "'img{border:0; cursor:hand;}')" & n &_
  Tab3 & CF1 & "'#imgU{position:absolute;}')" & n &_
  Tab3 & CF1 & "'#imgR{position:absolute;" & CF3 _
             & "oft.BasicImage(Rotation=1);}')" & n &_
  Tab3 & CF1 & "'#imgL{position:absolute;" & CF3 _
             & "oft.BasicImage(Rotation=3);}')" & n &_
  Tab3 & CF1 & "'</style>'+c60+'script language=""javaScript"">')" & n &_
  Tab3 & CF1 & "'var i=0;')" & n &_
  Tab3 & CF1 & "'function flip(d){')" & n &_
  Tab3 & CF1 & "'if(i==0){" & CF2 & "U" & CF4 & "hidden"";')" & n &_
  Tab3 & CF1 & "'" & CF2 & "L" & CF4 & "hidden"";')" & n &_
  Tab3 & CF1 & "'" & CF2 & "R" & CF4 & "visible"";')" & n &_
  Tab3 & CF1 & "'i=1;}else{if(i==3){" & CF2 & "R" & CF4 _
             & "hidden"";')" & n &_
  Tab3 & CF1 & "'" & CF2 & "L" & CF4 & "hidden"";')" & n &_
  Tab3 & CF1 & "'" & CF2 & "U" & CF4 & "visible""; i=0;}else{')" & n &_
  Tab3 & CF1 & "'if(i==1){" & CF2 & "U" & CF4 & "hidden"";')" & n &_
  Tab3 & CF1 & "'" & CF2 & "R" & CF4 & "hidden"";')" & n &_
  Tab3 & CF1 & "'" & CF2 & "L" & CF4 & "visible""; i=3;')" & n &_
  Tab3 & CF1 & "'}}}}')" & n &_
  Tab3 & CF1 & "c60+'/script></head><body>');" & n &_
  Tab3 & CF1 & "'<img id=""imgU" & CF5 & "1" & CF6 _
             & "Up\')"">');" & n &_
  Tab3 & CF1 & "'<img id=""imgR" & CF5 & "1" & CF6 _
             & "Right\')"">');" & n &_
  Tab3 & CF1 & "'<img id=""imgL" & CF5 & "1" & CF6 _
             & "Left\')"">');" & n &_
  Tab3 & CF1 & "'</body></html>');" & n &_
  Tab2 & "}" & n &_
  Tab1 & chr(60) & "/script>" & n &_
  Tab1 & "<title>MyJPGs</title>" & n & "</head>" & n & "<body>" & n

dim i,thumb,thumbFileName,htmlWrite,j,jpeg
  dim jpegFileName,src,onC,ask: ask = true

for i=1 to thumbNumbOf
    thumb = thumbArr(i)
    thumbFileName = fso.getFileName(thumb)

htmlWrite = false
    for j=1 to jpegsNumbOf
      jpeg = jpegsArr(j)
      jpegFileName = fso.getFileName(jpeg)
      if(thumbFileName = jpegFileName)then
             htmlWrite = true: exit for
      end if
    next

if(htmlWrite)then
       src = mid(thumb, lngth0)
       src = replace(src, "\", "/")
       onC = mid(jpeg, lngth1)
       onC = fso.getParentFolderName(onC)
       onC = replace(onC, "\", "/")
       if(len(onC))then onC = "+'" & onC & "/'"
       htmFileB.writeLine tab1 & "<img src=""" &_
             src & """ onClick=""s(p" & onC & ",'"_
             & jpegFileName & "');"">"
    elseIf(ask)then
       if(vbYes = msgBox("Delete this thumb (not found the big one)" &_
                        vbLf & thumb, vbYesNo +vbDefaultButton2, "?"))_
       then
             fso.deleteFile thumb, true
             deletedThumbs = deletedThumbs +1
       else
             ask = false
       end if
    end if
  next
  htmFileB.writeLine "</body>" & n & "</html>"
end sub
</SCRIPT>
</JOB>

The freeware program called "JAlbum", which can be used to make the thumbnails, is much
better than the Batch feature by PE2, but it cannot put your thumbs on only one page, etc...

"pdfNot2Photoshop.VBS"

Right click a JPG picture and Edit. (WinXP, danish version).
Write the following 3 lines into a file named "jpg2PhotoShop.REG" and run the REG file.
REGEDIT4
[HKEY_CLASSES_ROOT\jpegfile\shell\edit\command]
@="C:\\Programmer\\Adobe\\Photoshop Elements 2\\PhotoshopElements.exe \"%1\""

Below is a better version in VBS, instead of the above REG file. (PE3 is included).
"jpg2Photoshop.VBS": (Updated May 16, 2005)

' jpg2Photoshop.VBS
' Edit Jpeg files in Photoshop Elements by right click.

option explicit
dim RegV, Photoshop, FSO, WSO

set WSO= createObject("wScript.shell")
set FSO= createObject("scripting.fileSystemObject")

const reg1= "HKCR\jpegfile\shell\Edit\command\"
const reg2= "HKCR\ACDSee.JPG\shell\Edit\command\"

Photoshop= GetPhotoshop()

if not(FSO.fileExists(Photoshop))then
  msgBox "Not found Photoshop", 4112, ":-("
else
  RegV = Photoshop & " ""%1"""
  WSO.regWrite Reg1, RegV, "REG_SZ"
  on error resume next
  WSO.regRead(left(Reg2,16))
  if not cBool(err) then
    WSO.regWrite Reg2, RegV, "REG_SZ"
    WSO.regDelete "HKCR\ACDSee.JPG\shell\edit\ddeexec\"
  end if
  msgBox "Found Photoshop:" & vbLf & vbLf & Photoshop, 4160, ":-)"
end if

set WSO= nothing: set FSO= nothing

function GetPhotoshop()
  dim F, File, Element, Folder
  on error resume next
  Folder= WSO.expandEnvironmentStrings("%ProgramFiles%")
  if not FSO.folderExists(Folder) then Folder= "C:\Progra~1"
  for each Element in array( _
      "\Adobe\Photoshop Elements 3.0\Photoshop Elements 3.0.exe",_
      "\Adobe\Photoshop Elements 2\PhotoshopElements.exe")
    File= Folder & Element
    set F= FSO.GetFile(File)
    if err then
      err.clear
    else exit for
    end if
  next
  GetPhotoshop = F.shortPath
end function

"Photoshop.VBS": (experimental file)

' Purpose: Show how to do automation task in Photoshop PE2.
' Tested in Win98SE, (danish version).
' This file: \WINDOWS\Application Data\Mi
'             crosoft\Internet Explorer\Quick Launch\Photoshop.VBS

dim photoshop, wso, appReady
photoshop = "C:\Programmer\" &_
            "Adobe\Photoshop Elements 2\PhotoshopElements.exe"

set wso = wScript.createObject("wScript.shell")
appReady= wso.appActivate("Adobe Photoshop")

if not appReady then
  wso.run """" & photoshop & """"
  wScript.sleep 5200
  msgBox "When Photoshop is ready, THEN press a " &_
         "key to continue ...", 48, "Wait"
  appReady = wso.appActivate("Adobe Photoshop")
end if

if appReady then
  wso.sendkeys "^n1~^vc"
end if

' Alt key: %
' Enter:   ~
' Ctrl:    ^

' "^n1~^vc" would do the same as "%fn1{tab 10} {f4}c".
' "^n" or "%fn": The same as Ctrl+N for a New Picture.
' "1~" or "1{tab 10} ": 1 as name (and Enter, or 10 TAB+Space).
' "^v" or "{f4}" is the same as Ctrl+V, or F4, or Shift+Insert.
' "c" for the Crop Tool.

' Benny Pedersen,
' URL: http://home1.stofanet.dk/photo/

' If you have to work out 1000 JPG files, with same/some task, and
' have trouble with your modification of my script, then you could
' upload my above ideas, (or my URL) along with your task, here:
' www.google.com/groups?lr=&group=microsoft.public.scripting.wsh

Refer to my URL, or my script and write your questions about WSH, or take a look.

"Identical.vbs": (4096 byte)

' Identical.vbs | Somehow similar to Identical.wsf, (Recovery, Page 2).
'
' Identical.vbs takes two folder arguments which it uses
' to get all the filenames, simply renames any identical
' file of the second argument, using a basename based on
' the first argument.
'
' EX. The first argument could be the CDROM drive, "D:\"
'     e.g. the second argument "c:\public\".
'
'     If a file is named "D:\Hello.jpg" and identical to
'     a file named "c:\public\jpegFiles\8.jpg", then the
'     file "8.jpg" could be renamed to "8[ Hello ].jpg".
'
' PS. As usual: Subfolders are included, and you may use
'     drag and drop of file(s) and/or folder(s) instead,
'     but if more than 2 are dropped, only the first two
'     arguments are used in the dialogue, "What folder?"

dim scr: scr = " """ & wScript.ScriptFullname & """"
dim wso: set wso = wScript.createObject("wScript.shell")

if(inStr(lCase(wScript.fullname), "wscript.exe"))then
  dim i:for each i in wScript.arguments:scr=scr & " """ & i & """":next
  wso.run "cScript.exe" & scr, 0: set wso=nothing: wScript.quit
else dim noDiff: noDiff = getNoDiff(scr,wso): dim n: n = vbCrLf
  dim fso: set fso = createObject("scripting.fileSystemObject")
  scr = fso.getFileName(replace(scr,"""",""))
  dim r,path1,path2,arr1,arr2,uB1,uB2,i1,f1,s1,i2,f2: r = 0
end if

const subFolders1 = true, subFolders2 = true, ext = "JPG" '[uppercase]
path1= wso.specialFolders("MyDocuments")& "\Lost\" '[suggest default1]
path2= wso.specialFolders("MyDocuments")& "\Mark\" '[suggest default2]

'**Start Encode**:' [if vbe, not vbs].
path1= getPath(scr,string(5,n) & "First path:", path1, false)
path2= getPath(scr,string(5,n) & "Second path:", path2, true)
arr1 = split(getFileList(path1,subFolders1,""),"*")
arr2 = split(getFileList(path2,subFolders2,""),"*")
uB1  = uBound(arr1): if uB1<0 then uB1=0
uB2  = uBound(arr2): if uB2<0 then uB2=0

for i1=1 to uB1
  f1 = arr1(i1)
  s1 = fso.getFile(f1).size
  for i2=1 to uB2
    f2 = arr2(i2)
    if(f2<>"")then
      if(s1=fso.getFile(f2).size) _
      then if isIdentical(f1,f2)then r = renf2(f1,arr2(i2),r)
    end if
  next
next

msgBox path1 & n & "Found:" & vbTab & uB1 & n & n & path2 _
     & n & "Found:" & vbTab & uB2 & n & n & "Renamed:" _
     & vbTab & r & " " & ext & "-file(s).", 64, scr

function getFileList(folderSpec, recurse, list)
  dim f
  for each f in fso.getFolder(folderSpec).files
    if(uCase(fso.getExtensionName(f)) = ext)then list=list & "*" & f
  next
  if(recurse)then
    for each f in fso.getFolder(folderSpec).subfolders
      getFileList f, recurse, list
    next
  end if
  getFileList = list
end function

function getPath(title, byVal msg, byVal default, byVal bool)
  dim p: bool = abs(bool): on error resume next
  if(wScript.arguments.count > bool)then
    p= wScript.arguments(bool): default = fso.getFolder(p)
    if(err)then default = fso.getParentFolderName(p)
  end if: default = replace(default & "\","\\","\")
  p = replace(trim(inputBox(msg,title,default)),"""","")
  if(p="")then wScript.quit(0)
  err.clear: p= replace(fso.getFolder(p) & "\","\\","\")
  if(err)then
    msg = "Path not found:" & n & p & n & n
    msgBox msg & n & "Quit:",48,"Error": wScript.quit(1)
  end if: getPath = p' [p ending with a backslash]
end function

function getNoDiff(scr,wso)
  on error resume next
  getNoDiff = wso.exec("fc.exe" & scr & scr).stdOut.readAll
  getNoDiff = mid(getNoDiff, inStrRev(getNoDiff, "FC: "))
  if 1<>inStr(getNoDiff,"FC")then inputBox"Error",,"[L92]":wScript.quit
  getNoDiff = replace(getNoDiff, vbCrLf, empty)
end function

function isIdentical(f1,f2)
  if(inStr(wso.exec("fc.exe /lb1 """ & f1 & """ """ & f2 & """") _
  .stdOut.readAll, noDiff))then isIdentical = true
end function

function renf2(byVal f1, byRef f2, count)
  f1 = fso.getBaseName(f2) & "[ " & fso.getBaseName(f1) & " ]." & ext
  f1 = fso.getParentFolderName(f2) & "\" & f1
  fso.moveFile f2,f1: f2=empty
  renf2 = count +1
end function

set wso=nothing: set fso=nothing

Better is the WSF version on page 2, which takes only one argument.

Recovery page including more useful scripts, e.g. "jpg2numbers.vbs", etc...

Nearby my home in Kolding (Denmark)
June 17, 2004 - 04:20 AM		June 23, 2004 - 05:09 AM